FreeRTOS 整体架构图集

.global _start
_start:
    csrw    mstatus, zero            # 关中断
    la      sp, __stack_top          # 1) 栈顶（来自链接脚本 .ld）

    /* 2) 搬 .data(Flash→RAM)、清 .bss —— 此处省略循环 */

    call    main                     # 进入 C 世界
5:  wfi
    j       5b

    la      t0, freertos_risc_v_trap_handler
    csrw    mtvec, t0                # ★ mtvec = 统一 trap 入口（直接模式）

int main(void)
{
    prvInitHardware();                 /* 时钟/外设/CLINT（BSP） */

    xTaskCreate(vTaskA, "A", 256, NULL, tskIDLE_PRIORITY + 2, NULL);
    xTaskCreate(vTaskB, "B", 256, NULL, tskIDLE_PRIORITY + 1, NULL);

    vTaskStartScheduler();             /* 不返回 */
    for (;;) {}
}

pxPortInitialiseStack:
    addi a0, a0, -portWORD_SIZE
    store_x x0, 0(a0)                   # 临界区嵌套计数 = 0

    addi a0, a0, -(22 * portWORD_SIZE)  # x10..x31
    store_x a2, 0(a0)                   # pvParameters → x10/a0（任务参数）

    addi a0, a0, -(6 * portWORD_SIZE)   # x5..x9 + x1(ra)
    load_x  t0, xTaskReturnAddress
    store_x t0, 0(a0)                   # ra = 任务"返回"地址

    csrr t0, mstatus
    andi t0, t0, ~0x8                   # 清 MIE
    addi t1, x0, 0x188 ; slli t1, t1, 4 # t1 = 0x1880 = MPIE | MPP=Machine
    or   t0, t0, t1
    addi a0, a0, -portWORD_SIZE
    store_x t0, 0(a0)                   # mstatus 入栈

    addi a0, a0, -portWORD_SIZE
    store_x a1, 0(a0)                   # pxCode 入栈（= pxTopOfStack 指向处）
    ret

BaseType_t xPortStartScheduler( void )
{
    extern void xPortStartFirstTask( void );

    vPortSetupTimerInterrupt();                 /* 1) 配机器定时器 */
    __asm volatile ( "csrs mie, %0" :: "r"(0x880) );  /* 2) 开 MTIE+MEIE */
    xPortStartFirstTask();                      /* 3) 切到第一个任务（不返回）*/
    return pdFAIL;
}

void vPortSetupTimerInterrupt( void )   /* weak，可被应用覆盖 */
{
    volatile uint32_t * const pulTimeHigh = (volatile uint32_t*)(configMTIME_BASE_ADDRESS + 4);
    volatile uint32_t * const pulTimeLow  = (volatile uint32_t*)(configMTIME_BASE_ADDRESS);
    volatile uint32_t ulHartId;
    uint32_t ulCurrentTimeHigh, ulCurrentTimeLow;

    __asm volatile ( "csrr %0, mhartid" : "=r"(ulHartId) );

    pullMachineTimerCompareRegister =
        (volatile uint64_t*)(configMTIMECMP_BASE_ADDRESS + ulHartId * sizeof(uint64_t));

    do {                                     /* 原子读 64 位 mtime */
        ulCurrentTimeHigh = *pulTimeHigh;
        ulCurrentTimeLow  = *pulTimeLow;
    } while (ulCurrentTimeHigh != *pulTimeHigh);

    ullNextTime  = ((uint64_t)ulCurrentTimeHigh << 32) | ulCurrentTimeLow;
    ullNextTime += uxTimerIncrementsForOneTick;        /* = CPU_CLOCK_HZ / TICK_RATE_HZ */
    *pullMachineTimerCompareRegister = ullNextTime;     /* 到期触发第一个 Tick */
}

__asm volatile ( "csrs mie, %0" :: "r"(0x880) );
//  0x080 = bit7  MTIE  机器定时器中断
//  0x800 = bit11 MEIE  外部中断

xPortStartFirstTask:
    load_x  sp, pxCurrentTCB            # sp = &pxCurrentTCB
    load_x  sp, 0(sp)                   # sp = pxCurrentTCB->pxTopOfStack（首字段）

    load_x  x1, 0(sp)                   # x1/ra = 偏移0 = pxCode（任务入口）
    # portasmRESTORE_ADDITIONAL_REGISTERS   # 恢复 chip-specific 寄存器

    load_x  x5, 1*portWORD_SIZE(sp)     # x5 = 初始 mstatus
    addi    x5, x5, 0x08                # 置 MIE（因下面用 ret 而非 mret）
    csrw    mstatus, x5                 # ★ 此刻起中断开启

    load_x  x7,  5*portWORD_SIZE(sp)    # t2
    load_x  x8,  6*portWORD_SIZE(sp)    # s0/fp
    # … 恢复 x9..x31 …
    # 恢复该任务临界区嵌套计数 → xCriticalNesting

    addi    sp, sp, portCONTEXT_SIZE    # 弹整帧
    ret                                 # ★ 跳到 ra=pxCode，进第一个任务

freertos_risc_v_trap_handler:
    portcontextSAVE_CONTEXT_INTERNAL      # 保存到任务栈；更新 pxCurrentTCB->pxTopOfStack
    csrr a0, mcause
    csrr a1, mepc
    bge  a0, x0, synchronous_exception     # 最高位=0 → 同步异常

asynchronous_interrupt:                    # ── 中断 ──
    store_x a1, 0(sp)                     # 保存原 mepc
    load_x  sp, xISRStackTop              # ★ 切到专用中断栈（非 mscratch）
    j handle_interrupt

synchronous_exception:                     # ── 异常（含 ecall 让出）──
    addi a1, a1, 4                        # mepc 前进一条（跳过 ecall）
    store_x a1, 0(sp)
    load_x  sp, xISRStackTop
    j handle_exception

handle_interrupt:                          # 是否机器定时器？ mcause==(1<<(xlen-1))|7
    li  t0, 1 ; slli t0, t0, __riscv_xlen-1 ; addi t1, t0, 7
    bne a0, t1, application_interrupt_handler
    portUPDATE_MTIMER_COMPARE_REGISTER     # 重配 mtimecmp（见步骤 14）
    call xTaskIncrementTick
    beqz a0, processed_source             # 没解阻塞 → 不切换
    call vTaskSwitchContext
    j processed_source

handle_exception:
    li  t0, 11                            # 11 = M-mode ecall（即 portYIELD）
    bne a0, t0, application_exception_handler
    call vTaskSwitchContext                # ecall 让出 → 直接切换

processed_source:
    portcontextRESTORE_CONTEXT            # 从（新）任务栈恢复；mret

.macro portUPDATE_MTIMER_COMPARE_REGISTER
    load_x a0, pullMachineTimerCompareRegister   # a0 = &mtimecmp
    load_x a1, pullNextTime                       # a1 = &ullNextTime
    ld     t2, 0(a1)                              # t2 = ullNextTime
    sd     t2, 0(a0)                              # mtimecmp = ullNextTime
    ld     t0, uxTimerIncrementsForOneTick
    add    t4, t0, t2                             # 下一刻
    sd     t4, 0(a1)                              # ullNextTime += 一个 Tick
.endm